Exemple d'architecture à trois couches en Visual Basic

Exemple d'architecture à trois couches en Visual Basic ♪

Article lu fois.

L'auteur

Inconnu

L'article

Publié le 17 mars 2003 - Mis à jour le 3 janvier 2013

Version PDF Version hors-ligne

ePub, Azw et Mobi

Liens sociaux

I. Exemple d'application classique▲

Prenons en exemple une application très simple de gestion de comptes bancaires. Les données sont stockées dans une base composée de ces trois tables :

Image non disponible

Table tPersonne :		Titulaires des comptes
Table tCompte :		Les comptes bancaires
Table tOperation :		Opérations sur les comptes

Pour voir la structure des tables en détail, Cliquez ici.

Dans la feuille ci-contre, l'utilisateur demande l'affichage des comptes d'un client en entrant l'identifiant du client, puis en cliquant sur le bouton "Afficher".

Image non disponible

Voici une façon simple de gérer l'affichage des comptes dans la datagrid, sur l'évènement Click() du bouton :

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.

Private Sub btnSearch_Click()

Dim cnn As ADODB.Connection, rst As ADODB.Recordset, sql As String

If IsNumeric(Text1.Text) Then

    sql = "SELECT tCompte.Co_Numero, tCompte.Co_DateCreation, tCompte.Co_Solde FROM tCompte" & _
          " WHERE Co_IdProp=" & Text1.Text

    Set rst = New ADODB.Recordset
    Set cnn = New ADODB.Connection

    cnn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\db.mdb" & _
             ";Persist Security Info=False"
    rst.CursorLocation = adUseClient
    rst.Open sql, cnn, adOpenForwardOnly, adLockReadOnly
    Set rst.ActiveConnection = Nothing
    Set DataGrid1.DataSource = rst
    cnn.Close
Else
    MsgBox "L'identifiant d'un client est un numérique.", vbCritical, "Erreur de saisie"
End If

End Sub

Si le contenu du champ texte est numérique, une connexion est créée, les comptes sont récupérés dans un recordset qui devient la source de la datagrid.

L'affichage des comptes d'une personne peut être scindé en trois parties distinctes :

l'interface utilisateur ;
la logique de l'application : vérification de l'identifiant saisi et lecture du compte dans la base ;
connexion à la base de données et ouverture d'un recordset.

Le code source ci-dessus contient donc ces trois parties, alors qu'elles devraient être clairement distinctes. Cela permettrait de réutiliser le code qui crée une connexion à la base de données, et celui qui retrouve les comptes bancaires d'une personne. De façon générale, il vaut mieux programmer une application en séparant ces 3 fonctions : présentation, logique de l'application, et stockage des données.

II. Rôle de chacune des couches▲

La couche présentation :

affiche les données ;
envoie les demandes de l'utilisateur à la couche métier pour qu'elle les effectue ;
reçoit les résultats renvoyés par la couche métier et les affiche.

La couche métier (logique de l'application) :

reçoit et analyse les demandes de l'utilisateur ;
retrouve et modifie les données via la couche données ;
renvoie les résultats à la couche présentation.

La couche données :

modifie les données ;
récupère les données ;
assure la sécurité et l'intégrité des données.

III. Avantages de cette architecture▲

Séparer l'application en trois couches a de nombreux avantages, en voici une liste non exhaustive :

la gestion des données et la logique métier peuvent être indépendantes du type d'interface :
La logique de l'application et ses données pourront être utilisées par une interface Windows ou par un site ASP par exemple ;
les couches métier et données sont encapsulées :
ces couches assurent l'intégrité des données en analysant les demandes du client avant de les effectuer, et on gagne donc en robustesse. Pendant la réalisation de la couche métier, on peut se concentrer sur la logique de l'application et l'intégrité des données, sans se soucier de la présentation, et la maintenance en devient plus facile ;
les couches métier et données peuvent être placées sur un serveur ou chacune sur un serveur distinct.
- La couche présentation n'accédant pas directement aux données, la configuration de l'accès aux données ne se fait alors que sur le serveur où réside la couche données.
- Si la couche métier ou celle des données est modifiée, il n'y a pas de réinstallation à faire sur les postes clients.

IV. Exemple d'architecture à trois couches▲

Nous allons reprendre l'application de gestion de comptes bancaires, qui nous avait servi d'exemple.
La couche présentation sera un EXE standard, et les couches métier et données seront chacune une Dll ActiveX. Commençons par la couche des données.

IV-A. Couche données▲

Cette couche aura donc la forme d'une dll ActiveX. Pour créer ce type de projet, cliquez sur le menu Fichier -> Nouveau projet, puis sur DLL ActiveX. Allez dans les propriétés du projet et saisissez "Data" pour le nom du projet. La classe Class1 a été créée par défaut, renommez-la en clsData. Ce sera la seule classe contenue dans cette couche.

La classe clsData doit pouvoir : ouvrir une connexion à la base de données, et renvoyer un recordset déconnecté à partir d'une requête passée en paramètre.

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.

Option Explicit

Public Enum DataErrorEnum
    dtErrorConnexion = 4000
    dtErrorOpenRecordset = 4001
    dtErrorGeneral = 4002
End Enum

Private m_baseDeDonnees As String
Private m_chaineDeConnexion As String

Private Sub Class_Initialize()

  m_baseDeDonnees = App.Path & "\db.mdb"
  m_chaineDeConnexion = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & m_baseDeDonnees & _
                      ";Persist Security Info=False"
End Sub

Nous avons tout d'abord une énumération qui représente les numéros d'erreurs qui peuvent être créées par cette classe. Ces erreurs peuvent être signalées à la couche métier. La procédure Class_Initialize() est exécutée à l'initialisation de la classe. C'est à ce niveau que nous initialisons les variables qui contiennent les paramètres de notre connexion.

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.

Private Function CreeConnexion() As ADODB.Connection

  Dim cnn As ADODB.Connection

  On Error GoTo fail
  Set cnn = New ADODB.Connection
  cnn.Open m_chaineDeConnexion
  Set CreeConnexion = cnn
  Exit Function
  fail:
  Err.Raise dtErrorConnexion, "Data.clsData", _
            "La connexion à la base de données a échoué." & vbCrLf & Err.Number & ": " & Err.Description
End Function

Private Function CreeRecordset(sql As String) As ADODB.Recordset

  Dim cnn As ADODB.Connection, rst As ADODB.Recordset

  On Error GoTo fail

  Set cnn = CreeConnexion()

  Set rst = New ADODB.Recordset
  rst.CursorLocation = adUseClient
  rst.Open sql, cnn, adOpenForwardOnly, adLockReadOnly
  Set rst.ActiveConnection = Nothing

  cnn.Close
  Set cnn = Nothing

  Set CreeRecordset = rst
  Exit Function

  fail:
  Select Case Err.Number
      Case dtErrorConnexion:
          Err.Raise dtErrorConnexion, "Data.clsData", Err.Description
      Case Else
          Err.Raise dtErrorOpenRecordset, "Data.clsData", _
            "L'ouverture d'un recordset a échoué." & vbCrLf & Err.Number & ": " & Err.Description
  End Select

End Function

La fonction CreeConnexion() instancie un objet ADODB.Connection, se connecte à la base de données et renvoie l'objet instancié.

La fonction CreeRecordset() crée puis renvoie un recordset déconnecté, le code sql de la requête devant être passé en paramètre.

Nous renvoyons un recordset déconnecté, car un recordset connecté qui est transféré sur le réseau, conserve avec lui toutes les informations nécessaires pour rester lié à sa source de données.

Pour que le recordset soit déconnecté, vous devez :

donner à la propriété CursorLocation la valeur adUseClient, et ceci avant d'ouvrir le recordset. Ainsi le curseur sera géré du côté client ;
donner à la propriété ActiveConnection la valeur Nothing, après l'ouverture du recordset. Cela a pour effet de déconnecter le recordset de sa source de données.

En utilisant cette méthode, le recordset est transféré du serveur vers le client, morceau par morceau. Il faut donc plusieurs allers-retours entre le serveur et le client pour que le recordset soit totalement transféré, ce qui n'est pas l'idéal. Ceci peut-être encore amélioré en utilisant les composants RDS pour accéder aux données. Pour plus d'informations sur RDS, voir la documentation sur MSDN.

Ici la valeur choisie pour le "locktype" du recordset est adLockReadOnly, parce que les enregistrements n'ont pas besoin d'être modifiables par le client.

IV-B. Couche métier▲

Nous allons créer cette couche sous la forme d'une autre dll ActiveX. Tout d'abord le projet Data doit avoir été compilé. Puis sans fermer le projet, cliquez sur le menu Fichier -> Ajouter un projet, et sélectionnez DLL ActiveX. Renommez le nouveau projet en "Rules". La couche métier va utiliser la couche données, donc l'activeX "Data" doit être ajouté dans les références du projet.

La couche données contiendra deux classes. La classe clsServices qui nous fournira les comptes de quelqu'un, ainsi que les opérations d'un compte. Et clsCompte qui nous permettra de lire ou de modifier un compte. Voici le code source de la classe clsServices :

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.

Option Explicit

Function ListeComptes(idProprietaire As Long) As ADODB.Recordset

Dim objData As clsData, sql As String

On Error GoTo fail

sql = "SELECT * FROM tCompte WHERE co_IdProp=" & idProprietaire

Set objData = New clsData
Set ListeComptes = objData.CreeRecordset(sql)
Set objData = Nothing
Exit Function

fail:
Err.Raise Err.Number, Err.Source, Err.Description

End Function


Function ListeOperations(idCompte As Long, dateOperations As Date) As ADODB.Recordset

Dim objData As clsData, sql As String

On Error GoTo fail

sql = "SELECT * FROM tOperation WHERE (op_compteS=" & idCompte & ")"
If IsDate(dateOperations) Then sql = sql & "AND (co_DateCreation=#" & dateOperations & "#)"

Set objData = New clsData
Set ListeOperations = objData.CreeRecordset(sql)
Set objData = Nothing
Exit Function

fail:
Err.Raise Err.Number, Err.Source, Err.Description

End Function

Ces deux méthodes renvoient un recordset déconnecté. À ce niveau on se connecte à la base de données, mais l'on ne sait pas comment. Le type de base de données, son emplacement, la manière de se connecter, le mot de passe s'il y en a un, sont gérés dans la couche des données.

Voici la classe clsCompte :

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
80.
81.
82.
83.
84.
85.
86.
87.
88.
89.
90.
91.
92.
93.
94.
95.
96.
97.
98.
99.
100.
101.
102.
103.
104.
105.
106.
107.
108.
109.
110.
111.
112.
113.
114.
115.
116.
117.
118.
119.
120.
121.

Option Explicit

Public Enum RulesErrorEnum
   rlErrorReadOnly = 5000
   rlErrorIncorrectValue = 5001
End Enum

Private m_id As Long
Private m_numero As String
Private m_dateCreation As Date
Private m_solde As Single
Private m_idProprietaire As Long
Private m_loaded As Boolean

Property Get Id() As Long
Id = m_id
End Property

Property Get DateCreation() As Date
DateCreation = m_dateCreation
End Property

Property Get Numero() As String
Numero = m_numero
End Property

Property Let Numero(LeNumero As String)

If m_loaded Then
   Err.Raise rlErrorReadOnly, "Rules.clsCompte", "Le numéro d'un compte ne peut pas être modifié."
Else
   If IsNull(LeNumero) Or (Not IsNumeric(LeNumero)) Then
      Err.Raise rlErrorIncorrectValue, "Rules.clsCompte", "La valeur spécifiée pour un numéro de compte est incorrecte."
   Else
      m_numero = LeNumero
   End If
End If

End Property

Property Get Solde() As Single
Solde = m_solde
End Property

Property Let Solde(nouveauSolde As Single)
m_solde = nouveauSolde
End Property

Property Get Proprietaire() As Long
Proprietaire = m_idProprietaire
End Property

Property Let Proprietaire(idProprietaire As Long)

If m_loaded Then
   Err.Raise rlErrorReadOnly, "Rules.clsCompte", "Le propriétaire d'un compte ne peut pas être modifié."
Else
   m_idProprietaire = idProprietaire
End If

End Property

Public Function Load(idCompte As Long) As Boolean

Dim objData As clsData, sql As String, rst As ADODB.Recordset

On Error GoTo fail

sql = "SELECT * FROM tCompte WHERE co_id=" & Id

Set objData = New clsData
Set rst = objData.CreeRecordset(sql)

If Not rst.EOF Then
   m_id = rst("co_Id").Value
   m_numero = rst("co_numero").Value
   m_dateCreation = rst("co_DateCreation").Value
   m_solde = rst("co_Idprop")
   m_loaded = True
   Load = True
End If
rst.Close
Set rst = Nothing
Exit Function

fail:
Err.Raise Err.Number, "Rules.clsCompte", Err.Description

End Function

Public Function Save() As Boolean

Dim objData As clsData, sql As String, cnn As ADODB.Connection

On Error GoTo fail

If Id() > 0 Then
   sql = "UPDATE tCompte SET solde=" & Solde() & " WHERE co_Id=" & Id()
Else
   sql = "INSERT INTO tCompte (co_solde,co_IdProp,co_DateCreation,co_numero) VALUES (" & _
      Solde & "," & Proprietaire() & ",#" & Format(Date, "mm/dd/yyyy") & "#,'" & Numero() & "')"
End If

Set objData = New clsData
Set cnn = objData.CreeConnexion()
cnn.Execute sql
Save = True

cnn.Close
Set cnn = Nothing
Set objData = Nothing
Exit Function

fail:
Err.Raise Err.Number, "Rules.clsCompte", Err.Description

End Function

Private Sub Class_Initialize()
m_dateCreation = Date
End Sub

Ceci n'est qu'un aperçu de ce que pourrait être la classe clsCompte dans une application complète. Elle doit contenir toutes les règles de fonctionnement relatives à un compte. Les valeurs des champs ne sont modifiables que par l'intermédiaire des propriétés de la classe, qui contrôlent leur modification. Par exemple, il est interdit de modifier le numéro du compte si celui-ci a déjà été créé.
Un compte est lu avec la méthode Load(). La méthode Save() permet d'ajouter un nouveau compte ou d'enregistrer les modifications effectuées sur un compte existant.

IV-C. Couche présentation▲

À ce stade nous n'avons plus qu'à programmer l'interface, qui affichera les données et effectuera les commandes demandées par l'utilisateur, et ceci simplement en manipulant les objets de la couche métier.

Pour créer cette couche, ajoutez un projet de type Exe Standard. Ajoutez l'activeX Rules dans ses références.

Voici ce que devient notre code source du premier chapitre, qui affichait les comptes d'une personne dans une datagrid :

Cacher/Afficher le codeSélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.

Private Sub btnSearch_Click()

Dim services As clsServices, rst As ADODB.Recordset

On Error GoTo fail
Set services = New clsServices
Set rst = services.ListeComptes(CLng(Text1.Text))
Set DataGrid1.DataSource = rst
Exit Sub

fail:
Select Case Err.Number
    Case 13:
        MsgBox "Vous devez saisir un numérique."
    Case Else:
        MsgBox Err.Source & ": " & "Erreur n° " & Err.Number & ": " & Err.Description
End Select

End Sub

Vous pouvez télécharger les sources.

Vous avez aimé ce tutoriel ? Alors partagez-le en cliquant sur les boutons suivants :

Copyright © 2003 Inconnu. Aucune reproduction, même partielle, ne peut être faite de ce site ni de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.